[SierraKomodo]

Basically, I'm thinking about writing a script but there's a few things I need to know before I can start:

First off, how do I make a script create a database, be able to open and read it, and perform commands based off whats in the database (Kind of like the CRS members database)

Poking through the CRS script didn't really give me any information that helped me much, and searching didn't yield any results that I could find.

Ideally, I'd be able to type in a command with a few arguments that would place the given arguments into the file.

I.E:

[command Word1 Word2 Word3

Then it's saved in the database with those three words.

Also, is there a way to have it write to a .txt file in a way that's readable and editable by notepad?

[Shnougle]

Well you can very easily write info to a text file or an ini file. It just depends on what information will be stored, how much of it, and how it will be read. If you just want to type the command and have it store a line in a text file:

Sub Event_Load()
FileName = "Whatever you want your filename to be.txt"
End Sub

Sub Event_Usertalk(Username, Flags, Message, Ping)
If Left(Message, Len(Split(Message)(0))) = "whatever" '\\Your command
X = Split(Message, Split(Message)(0) & " ")(1) '\\What will be written to the file.
Set fso = CreateObject("Scripting.FileSystemObject") 
Set File = FSO.OpenTextFile(BotPath & FileName, 8, True) '\\Open The text file so that you can write to it.
File.WriteLine X        '\\Write to the file
AddQ X & " has been written to " & FileName
File.Close  '\\Close the file
End if
End Sub

That would write whatever you said into the text file as a new line which could be read using the .ReadLine method. But this is a super simple way of doing it. If you outline more of what your trying to do maybe i can give you a better example.

This post has been edited by Shnougle: March 01, 2010 - 10:01 PM

[Tuck]

Use the FSO, File System Object

[The-Black-Ninja]

What specifically were you looking for in the CRS that you weren't able to find? I could write you a very basic template where it creates the db if it isn't there, automatically adds an entry, then reads that entry back to you on event_load.

[SierraKomodo]

In the CRS script, basically I was looking for a line that would say something about writing to or reading a file (Other than writing to or reading from settings) that would clue me in on how to do it myself. That strategy worked with quite a few things, but not in this instance.

I was aiming to set up a personal list of known hackers and what not that can easily be accessed through my bot, and added to in the same manner. The reason I want it in a text file I can open read and edit, is so I can open the file and use CTRL+F to quickly search through for certain usernames, though if there's a way to get the bot to search it for me that would be a plus.

What i'm looking at so far is 4 variables that I want to use, two of which would be given in the command
The username of whoever is 'reported'
A description (In the form of a string, after the first variable) that gives the offense
The username of the person that added him to the list
And a timestamp of when he was added

P.S. I know I could've just requested this script be done, but I wouldn't learn that way. I'll read through the link Tuck gave. This post was mostly for TBN to get what she asked for.

[Tuck]

If this is first time your trying to store values, i would suggest using

WriteSettingsEntry EntryName, EntryValue
GetSettingsEntry(EntryName)

would just save/load the values into/from Script.ini

This post has been edited by Tuck: March 01, 2010 - 11:08 PM

[SierraKomodo]

The WriteSettingsEntry and GetSettingsEntry are one of the things I got from poking through scripts (In particular, the CRS script.) Though, I'm wondering what from my concept can be considered a value that would be put in the scripts.ini file. With what I'm trying to do with the entries, it could easily come to a hundred lines in a couple weeks since I'm using BWHF to find hacks >.>

ALSO: Thanks to the posts here, I might be able to find what I need to find in the CRS script. The problem was that I just didn't know what to look for. We'll see shortly.

[The-Black-Ninja]

So you don't want me to give you a basic example so you're not looking through hundreds of line of code?

[SierraKomodo]

Oh, didn't mean that XD

The basic example would help out alot. I'm still not quit getting whats in the CRS Script. For example:

   crsDatabasePath = BotPath() & "MemberData.mdb"
   Set crsFSO = CreateObject("Scripting.FileSystemObject")
   If Not crsFSO.FileExists(crsDatabasePath) Then
      AddChat 16759296, "Welcome to the Clan Rank Script! You can customize the number and names of existing ranks inside crsClanRankScript.txt"
      AddChat 16759296, "Please note that all changes to the ", vbRed, "NUMBER OF EXISTING RANKS", vbCyan, " should be made ", vbRed, "BEFORE", vbCyan, " you start adding members!"
      AddChat 16759296, "You may customize the access level for each rank inside crsClanRankScript.txt"
      AddChat 10682112, "For help on common CRS questions and issues, visit:"
      AddChat 10682112, "http://www.stealthbot.net/forum/index.php?/topic/368-clan-rank-script-faqs-crs/"
	  AddChat 10682112, "Remember to state that this is the CRS edited by Sierra.Komodo when asking for help"
      crs_create_database '// Create the database
   Else
      crs_connect '// Connect to database
   End If

I don't quite know what the create database and connect ones do and how to get them to do what they do - I can give a guess on the former, but the latter I just can't figure out >.>

[Tuck]

SierraKomodo, on 02 March 2010 - 01:37 AM, said:

Oh, didn't mean that XD

The basic example would help out alot. I'm still not quit getting whats in the CRS Script. For example:

   crsDatabasePath = BotPath() & "MemberData.mdb"
   Set crsFSO = CreateObject("Scripting.FileSystemObject")
   If Not crsFSO.FileExists(crsDatabasePath) Then
      AddChat 16759296, "Welcome to the Clan Rank Script! You can customize the number and names of existing ranks inside crsClanRankScript.txt"
      AddChat 16759296, "Please note that all changes to the ", vbRed, "NUMBER OF EXISTING RANKS", vbCyan, " should be made ", vbRed, "BEFORE", vbCyan, " you start adding members!"
      AddChat 16759296, "You may customize the access level for each rank inside crsClanRankScript.txt"
      AddChat 10682112, "For help on common CRS questions and issues, visit:"
      AddChat 10682112, "http://www.stealthbot.net/forum/index.php?/topic/368-clan-rank-script-faqs-crs/"
	  AddChat 10682112, "Remember to state that this is the CRS edited by Sierra.Komodo when asking for help"
      crs_create_database '// Create the database
   Else
      crs_connect '// Connect to database
   End If

I don't quite know what the create database and connect ones do and how to get them to do what they do - I can give a guess on the former, but the latter I just can't figure out >.>

Uses FSO (File System Object) to check if the sql database file exists if not it will create it.

[The-Black-Ninja]

Okay, I'll write you something fast right now.

[SierraKomodo]

Alright, thanks. I should go experiment with the code, see what happens if I change something >.>

[The-Black-Ninja]

On reload, the bot will get reported. On the next reload, the bot will already be in the database, so it will retrieve the comments instead:

Script("Name") = "DBTest"
Script("Major") = 1
Script("Minor") = 4


Public dbConn, dbPath

     
Sub Event_Load()

   
   dbPath = BotPath() & "Data.mdb"
   
   '// Check if file exists with a FSO
   Set dbSO = CreateObject("Scripting.FileSystemObject")
   If NOT dbSO.FileExists(dbPath) Then
      AddChat vbGreen, "Database does not exist at: " & dbPath & " - Creating database"
      Call Create_DB() '// Create the database
   End If
      
   AddChat vbGreen, "Zomg!! Hacker found!"
   Call AddHacker(BotVars.Username, "Hacking n00b!")
End Sub


Public Sub Create_DB()

   '// Create the database using ADOX and a connection string
   Set Catalog = CreateObject("ADOX.Catalog")
   Catalog.Create "Provider=Microsoft.Jet.OLEDB.4.0;Jet OLEDB:Engine Type=5;Data Source=" & dbPath

   Call DB_Connect()

   '// Create colums and format them for data entry
   dbConn.Execute("CREATE TABLE `users` (`name` varchar(30), `comments` Text)")
   
   dbConn.Close
   Set Catalog = Nothing
End Sub


Public Sub DB_Connect()
   
   Set dbConn = CreateObject("ADODB.connection")
   dsn = "Driver={Microsoft Access Driver (*.mdb)};Dbq=" & dbPath
   dbConn.ConnectionString = dsn
   
   dbConn.Open
End Sub


Private Sub AddHacker(name, sComments)

   '// Connect to the database
   Call DB_Connect()
   
   '// Check if the user is in the database. 0 means they aren't in there.
   Set userExists = dbConn.Execute("SELECT COUNT(`name`) FROM `users` WHERE `name` ='" & name & "'")
   If userExists.Fields(0) > 0 Then
      AddChat vbGreen, name & " is already reported as a hacker. Retrieving info..."
      dbConn.Close
      Call GetHackerInfo(name)
   Else
      '// Add user to database. Since the comments colum is mainly accepting text, convert the variable to a string so the ' before the quotations won't error if someone decides to input all numbers.
      dbConn.Execute("INSERT INTO `users` (`name`, `comments`) VALUES ('" & name & "', '" & CStr(sComments) & "')")
      AddChat vbGreen, name & " reported as: " & sComments
   End If
   
   '// Close the connection
   Set userExists = Nothing
   
   '// Check if the connection is still open, if it's not already closed, close it
   If dbConn.State <> 0 Then dbConn.Close
End Sub


Private Sub GetHackerInfo(name)

   Call DB_Connect()
   
   Set userExists = dbConn.Execute("SELECT COUNT(`name`) FROM `users` WHERE `name` ='" & name & "'")
   If userExists.Fields(0) > 0 Then
      Set rs = dbConn.Execute("SELECT COUNT(`comments`) FROM `users` WHERE `name` ='" & name & "'")
      If LenB(rs.Fields(0)) = 0 Then    
         AddChat vbGreen, name & " is reported as a hacker without a reason."
      Else
         AddChat vbGreen, name & " is reported as a hacker with the reason: " & dbConn.Execute("SELECT `comments` FROM `users` WHERE `name` ='" & name & "'").Fields(0)
      End If
   End If
   
   Set userExists = Nothing
   Set rs = Nothing
   If dbConn.State <> 0 Then dbConn.Close
End Sub

[Tuck]

I actually made something like ninjas example (might help you to)

Script("Name") = "rp"
Script("Author") = "Tuck"
Script("Major") = 1
Script("Minor") = 0
Script("Revision") = 0
Script("Description") = "Report People."

private dbPath, Conn

Sub Event_Load()
    dbPath = BotPath() & "scripts\rp.mdb"
    If (CreateObject("Scripting.FileSystemObject").FileExists(dbPath)) Then
        Call Connect()
    Else
        CreateObject("ADOX.Catalog").Create "Provider=Microsoft.Jet.OLEDB.4.0;Jet OLEDB:Engine Type=5;Data Source=" & dbPath
        Call Connect()
        Conn.Execute("Create Table `Data` (`Account` Varchar(25) Not Null, `Reason` Text, `Time` Timestamp Not Null, `Username` Varchar(25) Not Null)")
    End If
    If (OpenCommand("report") Is Nothing) Then
        With CreateCommand("report")
            .RequiredRank = 200
            .Description = "Report <Username> [Reason]"
            .Parameters.Add .NewParameter("Username", False, "Word")
            .Parameters.Add .NewParameter("Reason", False, "String")
            .Save
        End With
    End If
    If (OpenCommand("reports") Is Nothing) Then
        With CreateCommand("reports")
            .RequiredRank = -1
            .Description = "List all reports"
            .Save
        End With
    End If
    If (OpenCommand("delreports") Is Nothing) Then
        With CreateCommand("delreports")
            .RequiredRank = -1
            .Description = "Delete all reports"
            .Save
        End With
    End If
End Sub

Private Sub Connect()
   Set Conn = CreateObject("ADODB.connection")
   Conn.ConnectionString = "Driver={Microsoft Access Driver (*.mdb)};Dbq=" & dbPath
   Conn.Open
End Sub

Sub Event_Close()
    On Error Resume Next
    Conn.Close
    Set Conn = Nothing
End Sub

Sub Event_Command(Command)
    If Not (Command.HasAccess And Command.IsValid) Then Exit Sub
    If (Command.IsLocal And Not IsOnline()) Then Command.Username = BotVars.Username
    If LCase(Command.Name) = "report" Then
        If Not LCase(Command.Argument("Username")) = LCase(Command.Username) Then
            Conn.Execute("Insert Into `Data` (`Account`, `Reason`, `Time`, `Username`) Values ('" & Command.Argument("Username") & "', '" & Command.Argument("Reason") & "', '" & Now() & "', '" & Command.Username & "')")
            Command.Respond(Command.Argument("Username") & " has been reported.")
        End If
    ElseIf LCase(Command.Name) = "reports" Then
        'Show all database entrys inside bot
        Set Data = Conn.Execute("Select * From `Data`")
        AddChat RGB(0, 204, 153), "Account | Reason | Time | Username"
        If (Not (Data.BOF Or Data.EOF)) Then
            Do Until Data.EOF
                AddChat RGB(0, 204, 153), Data.Fields(0) & " | " & Data.Fields(1) & " | " & Data.Fields(2) & " | " & Data.Fields(3)
                Data.MoveNext
            Loop
        Else
            AddChat RGB(0, 204, 153), "No reports."
        End If
    ElseIf LCase(Command.Name) = "delreports" Then
        Conn.Execute("Delete * From `Data`")
        Command.Respond("Deleted reports.")
    End If
End Sub

[SierraKomodo]

Thanks TBN. I'll look through the script, see if I can't figure out how you did it now and put it to test

[7thAce]

You mentioned something with BWHF. I have actually made a BWHF script that you may find useful. It uses a text file (with FSO), so you can learn from that.
I'll add comments too, let me edit my post.

Spoiler

      Script("Name")     = "BWHFcheck"
      Script("Author")   = "7thAce"
      Script("Major")    = 1
      Script("Minor")    = 3
      Script("Revision") = 1
      Script("Description") = "Checks the BWHF cache for hackers."
      
      'Changelog
      '1.3.1:
      'Whispered response.  Again.
      
      '1.3.0:
      'Rewrote the scan/interpret system to be a tad cleaner
      'Added ability to be on an IP
      
      '1.2.1:
      'Added cache count.
      
      '1.2.0:
      'Added following features:
      'User is either not a hacker, other realm hacker, or a hacker on your realm
      'Moderate security (Name and trigger security)
      'Recaches the page every 15 minutes (changeable)
      
      '1.1.1:
      'Whispered response.
      
      '1.1.0:
      'Marked realm.
      
      Public Whisperto
      
      Const UpdateTime = 15 '// Minutes between updates.
      Const BWHFcachepath = ""
      
      Sub event_load()
      If BWHFcachepath = vbnullstring Then Addchat vbred, "You must change the BWHFcachepath to your cache path.  Ex. C:Program FilesBWHFAgentHacker list cacheBWHF_hacker_list_cache.txt"
      Whisperto = 0
          CreateObj "LongTimer", "Recache"
          Recache.Enabled = True
          Recache.Interval = UpdateTime * 60
      End Sub
 
 Sub event_pressedenter(text)
    If left(lcase(text), 6) = botvars.trigger & "scan " Then
    Message = Text
    Vetothismessage()
     Call Event_Usertalk(Username, flags, message, ping)
     End if
End Sub
 
      Sub event_usertalk(Username, Flags, Message, Ping)
      If left(lcase(message), 6) = botvars.trigger & "scan " Then
    '// Is it our command?
      If instr(message, "/") > 0 Then
       AddQ "Please supply a valid username."
       Exit Sub
      End If
   '// 2nd word is the person we want to check for hacks
      Tocheck = split(message)(1)
   '// Set the FSO object
      Set FSO = CreateObject("Scripting.FileSystemObject")
   '// Open our text file.  1 means for reading, False will raise an error if the file doesn't exist.
      Set File = FSO.opentextfile(BWHFcachepath, 1, False)
   '// Split everything by each new line
      Lines = split(File.ReadAll, vbnewline)
      Haxxor = 0
   '// Script specific stuff
   '// Basically allows you to be on an IP
   '// and still have realm specific
   '// detection to work.
      MyServer = split(botvars.server, ".battle")(0)
      RealmIPID = Split("63.240 63.241 213.248 211.233")
      RealmName = Split("useast uswest europe asia iccup other")
      If instr(lcase(myserver), ".battle.net") = 0 Then
       For i = 0 to 3
        If left(myserver, len(realmipid(i))) = realmipid(i) Then
         MyServer = realmname(i)
        End If
       Next
      End If
   '// Loop through each line
       For i = 0 to ubound(lines) - 1
   '// Is the line something?
        If lines(i) <> vbnullstring Then
   '// Get the hacker's name
   '// Remember, the cache format is 0,name
   '// Where the number is the realm
        Haxname = right(lines(i), len(lines(i)) - 2)
   '// Get the realm
        Haxrealm = left(lines(i), 1)
   '// Does the hacker name match our search?
         If Haxname = tocheck Then
   '// Yes!  Let's tell the user that.
         Haxxor = 1
         Haxrealm = realmname(int(haxrealm))
   '// Is the hacker on this realm?
   '// Yep
          If haxrealm = myserver Then
           If whisperto = 1 Then
            AddQ "/w " & Username & " " & Tocheck & " hacks on this realm!"
           Else
            AddQ Tocheck & " hacks on this realm!"
           End If
           Exit Sub
          Else
   '// Nope
           If whisperto = 1 Then
            AddQ "/w " & Username & " " & Tocheck & " hacks, but not on this realm."
           Else
            AddQ Tocheck & " hacks, but not on this realm."
           End If
          End If
         End If
        End If
       Next
   '// So we went through the whole file
   '// And the person's name never showed up
   '// He doesn't hack, let's tell them that.
      If Haxxor = 0 Then
       If whisperto = 1 Then
        AddQ "/w " & Username & " " & Tocheck & " is not a hacker."
       Else
        AddQ Tocheck & " is not a hacker."
       End If
      End If
      End If
      End Sub
      
      Sub event_Whisperfromuser(Username, flags, message, ping)
   '// Allows for whispers
      If left(lcase(message), 6) = botvars.trigger & "scan " Then
      WhisperTo = 1
      Call Event_Usertalk(Username, flags, message, ping)
      End if
      End Sub
      
      Sub Recache_timer()
   '// Another use of FSO
   '// The script reloads the cache
   '// from the online database
   '// Set our FSO object
      Set FSO = CreateObject("Scripting.FileSystemObject")
   '// Same thing, but we use 2 to rewrite the entire file
   '// Everything is erased but rewritten
      Set File = fso.OpenTextFile(BWHFcachepath, 2, True)
   '// Don't ask
      File.writeline vbnullstring
   '// This connects to the internet and gets the online database
      Content = split(Scinet.openurl("http://bwhf.net/hackerdb/hackers?op=dhl"), vbnewline)
      If ubound(content) < 5 Then
   '// Nothing?  Let's avoid doing anything bad to our cache
       Addchat vbred, "Hacker list is empty, not recacheing the hacker list."
       Addchat vbred, "You may not be connected to the internet."
       Exit Sub
      End If
   '// Loop through the webpage
      For i = 0 to ubound(content)
   '// Write the hacker to the file
      File.writeline content(i)
      Next
   '// Confirmation that everything was all good.
      Addchat vbmagenta, "Recached hacker list.  " & Ubound(content) + 1 & " users are currently in the hacker database."
   '// Close the file at the end of using it 
   '// I may have forgotten that above :/
      File.Close
      End Sub

Edit: Haha, it's all trying to make you a better scripter.

[SierraKomodo]

Thx, Ace. I'll take a look at that one too XD

And I didn't even see Tucks >.>

Good god I'm being overwhelmed! XD

TBN:

Quote

[06:01:36 PM] Scripting runtime error '450' in DBTest.txt: (line 1; column 0)
[06:01:36 PM] Wrong number of arguments or invalid property assignment: 'Scripts'
[06:01:36 PM] Offending line: >>
[06:01:36 PM] Scripts loaded.
[06:01:36 PM] Zomg!! Hacker found!
[06:01:36 PM] Scripting runtime error '-2147217865' in DBTest: (line 57; column 0)
[06:01:36 PM] [Microsoft][ODBC Microsoft Access Driver] The Microsoft Jet database engine cannot find the input table or query 'users'. Make sure it exists and that its name is spelled correctly.
[06:01:36 PM] Offending line: >>
[06:01:36 PM] Scripting runtime error '-2147217865' in DBTest: (line 57; column 0)
[06:01:36 PM] [Microsoft][ODBC Microsoft Access Driver] The Microsoft Jet database engine cannot find the input table or query 'users'. Make sure it exists and that its name is spelled correctly.
[06:01:36 PM] Offending line: >>

[Tuck]

SierraKomodo, on 02 March 2010 - 03:02 AM, said:

Thx, Ace. I'll take a look at that one too XD

And I didn't even see Tucks >.>

Good god I'm being overwhelmed! XD

TBN:

change

Scripts("Name") = "DBTest"
Scripts("Major") = 1
Scripts("Minor") = 0

to

Script("Name") = "DBTest"
Script("Major") = 1
Script("Minor") = 0

And

dbConn.Execute("CREATE TABLE `users` (`name` varchar(30), `comments` Text")

To

dbConn.Execute("CREATE TABLE `users` (`name` varchar(30), `comments` Text)")

This post has been edited by Tuck: March 02, 2010 - 02:08 AM

[SierraKomodo]

Ace: What are the commands for your script? There's nothing showing up in the command manager

[Tuck]

SierraKomodo, on 02 March 2010 - 03:11 AM, said:

Ace: What are the commands for your script? There's nothing showing up in the command manager

If left(lcase(message), 6) = botvars.trigger & "scan " Then

.scan <arg>

[SierraKomodo]

Tuck: Error still comes up. Might be different from before, not sure but I'll copy it again anyway.

Quote

[06:12:22 PM] Scripting runtime error '-2147217865' in DBTest: (line 57; column 0)
[06:12:22 PM] [Microsoft][ODBC Microsoft Access Driver] The Microsoft Jet database engine cannot find the input table or query 'users'. Make sure it exists and that its name is spelled correctly.
[06:12:22 PM] Offending line: >>
[06:12:22 PM] Scripting runtime error '-2147217865' in DBTest: (line 57; column 0)
[06:12:22 PM] [Microsoft][ODBC Microsoft Access Driver] The Microsoft Jet database engine cannot find the input table or query 'users'. Make sure it exists and that its name is spelled correctly.
[06:12:22 PM] Offending line: >>

And I feel like an idiot there. Should've seen that one in his script >.>

ADD: /scan username comes up as an invalid command

[The-Black-Ninja]

Updated. It shouldn't be not finding that table because it's getting created in the event_load...

[SierraKomodo]

And, it seems the command works when another user uses it but wont work in console

Ok so, I'm over here poking through and testing three scripts at once now.. XD

I'm just gonna focus on one at a time, starting with TBN's

[Tuck]

SierraKomodo, on 02 March 2010 - 03:16 AM, said:

And, it seems the command works when another user uses it but wont work in console

Ok so, I'm over here poking through and testing three scripts at once now.. XD

I'm just gonna focus on one at a time, starting with TBN's

You need to delete the "Data.mdb" inside bot folder and do the 2 fixes i posted and reload scripts. (might need to disable the script to delete the file)

[7thAce]

It's not an internal command. I'll edit it real quick.
Fixed. Use it in your bot like an external command (.scan test)